<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package IPC::Cmd;

use strict;

BEGIN {

    use constant IS_VMS         =&gt; $^O eq 'VMS'                       ? 1 : 0;
    use constant IS_WIN32       =&gt; $^O eq 'MSWin32'                   ? 1 : 0;
    use constant IS_WIN98       =&gt; (IS_WIN32 and !Win32::IsWinNT())   ? 1 : 0;
    use constant ALARM_CLASS    =&gt; __PACKAGE__ . '::TimeOut';
    use constant SPECIAL_CHARS  =&gt; qw[&lt; &gt; | &amp;];
    use constant QUOTE          =&gt; do { IS_WIN32 ? q["] : q['] };

    use Exporter    ();
    use vars        qw[ @ISA $VERSION @EXPORT_OK $VERBOSE $DEBUG
                        $USE_IPC_RUN $USE_IPC_OPEN3 $CAN_USE_RUN_FORKED $WARN
                        $INSTANCES $ALLOW_NULL_ARGS
                        $HAVE_MONOTONIC
                    ];

    $VERSION        = '1.00';
    $VERBOSE        = 0;
    $DEBUG          = 0;
    $WARN           = 1;
    $USE_IPC_RUN    = IS_WIN32 &amp;&amp; !IS_WIN98;
    $USE_IPC_OPEN3  = not IS_VMS;
    $ALLOW_NULL_ARGS = 0;

    $CAN_USE_RUN_FORKED = 0;
    eval {
        require POSIX; POSIX-&gt;import();
        require IPC::Open3; IPC::Open3-&gt;import();
        require IO::Select; IO::Select-&gt;import();
        require IO::Handle; IO::Handle-&gt;import();
        require FileHandle; FileHandle-&gt;import();
        require Socket;
        require Time::HiRes; Time::HiRes-&gt;import();
        require Win32 if IS_WIN32;
    };
    $CAN_USE_RUN_FORKED = $@ || !IS_VMS &amp;&amp; !IS_WIN32;

    eval {
        my $wait_start_time = Time::HiRes::clock_gettime(&amp;Time::HiRes::CLOCK_MONOTONIC);
    };
    if ($@) {
        $HAVE_MONOTONIC = 0;
    }
    else {
        $HAVE_MONOTONIC = 1;
    }

    @ISA            = qw[Exporter];
    @EXPORT_OK      = qw[can_run run run_forked QUOTE];
}

require Carp;
use File::Spec;
use Params::Check               qw[check];
use Text::ParseWords            ();             # import ONLY if needed!
use Module::Load::Conditional   qw[can_load];
use Locale::Maketext::Simple    Style =&gt; 'gettext';

local $Module::Load::Conditional::FORCE_SAFE_INC = 1;

=pod

=head1 NAME

IPC::Cmd - finding and running system commands made easy

=head1 SYNOPSIS

    use IPC::Cmd qw[can_run run run_forked];

    my $full_path = can_run('wget') or warn 'wget is not installed!';

    ### commands can be arrayrefs or strings ###
    my $cmd = "$full_path -b theregister.co.uk";
    my $cmd = [$full_path, '-b', 'theregister.co.uk'];

    ### in scalar context ###
    my $buffer;
    if( scalar run( command =&gt; $cmd,
                    verbose =&gt; 0,
                    buffer  =&gt; \$buffer,
                    timeout =&gt; 20 )
    ) {
        print "fetched webpage successfully: $buffer\n";
    }


    ### in list context ###
    my( $success, $error_message, $full_buf, $stdout_buf, $stderr_buf ) =
            run( command =&gt; $cmd, verbose =&gt; 0 );

    if( $success ) {
        print "this is what the command printed:\n";
        print join "", @$full_buf;
    }

    ### run_forked example ###
    my $result = run_forked("$full_path -q -O - theregister.co.uk", {'timeout' =&gt; 20});
    if ($result-&gt;{'exit_code'} eq 0 &amp;&amp; !$result-&gt;{'timeout'}) {
        print "this is what wget returned:\n";
        print $result-&gt;{'stdout'};
    }

    ### check for features
    print "IPC::Open3 available: "  . IPC::Cmd-&gt;can_use_ipc_open3;
    print "IPC::Run available: "    . IPC::Cmd-&gt;can_use_ipc_run;
    print "Can capture buffer: "    . IPC::Cmd-&gt;can_capture_buffer;

    ### don't have IPC::Cmd be verbose, ie don't print to stdout or
    ### stderr when running commands -- default is '0'
    $IPC::Cmd::VERBOSE = 0;


=head1 DESCRIPTION

IPC::Cmd allows you to run commands platform independently,
interactively if desired, but have them still work.

The C&lt;can_run&gt; function can tell you if a certain binary is installed
and if so where, whereas the C&lt;run&gt; function can actually execute any
of the commands you give it and give you a clear return value, as well
as adhere to your verbosity settings.

=head1 CLASS METHODS

=head2 $ipc_run_version = IPC::Cmd-&gt;can_use_ipc_run( [VERBOSE] )

Utility function that tells you if C&lt;IPC::Run&gt; is available.
If the C&lt;verbose&gt; flag is passed, it will print diagnostic messages
if L&lt;IPC::Run&gt; can not be found or loaded.

=cut


sub can_use_ipc_run     {
    my $self    = shift;
    my $verbose = shift || 0;

    ### IPC::Run doesn't run on win98
    return if IS_WIN98;

    ### if we don't have ipc::run, we obviously can't use it.
    return unless can_load(
                        modules =&gt; { 'IPC::Run' =&gt; '0.55' },
                        verbose =&gt; ($WARN &amp;&amp; $verbose),
                    );

    ### otherwise, we're good to go
    return $IPC::Run::VERSION;
}

=head2 $ipc_open3_version = IPC::Cmd-&gt;can_use_ipc_open3( [VERBOSE] )

Utility function that tells you if C&lt;IPC::Open3&gt; is available.
If the verbose flag is passed, it will print diagnostic messages
if C&lt;IPC::Open3&gt; can not be found or loaded.

=cut


sub can_use_ipc_open3   {
    my $self    = shift;
    my $verbose = shift || 0;

    ### IPC::Open3 is not working on VMS because of a lack of fork.
    return if IS_VMS;

    ### IPC::Open3 works on every non-VMS platform, but it can't
    ### capture buffers on win32 :(
    return unless can_load(
        modules =&gt; { map {$_ =&gt; '0.0'} qw|IPC::Open3 IO::Select Symbol| },
        verbose =&gt; ($WARN &amp;&amp; $verbose),
    );

    return $IPC::Open3::VERSION;
}

=head2 $bool = IPC::Cmd-&gt;can_capture_buffer

Utility function that tells you if C&lt;IPC::Cmd&gt; is capable of
capturing buffers in it's current configuration.

=cut

sub can_capture_buffer {
    my $self    = shift;

    return 1 if $USE_IPC_RUN    &amp;&amp; $self-&gt;can_use_ipc_run;
    return 1 if $USE_IPC_OPEN3  &amp;&amp; $self-&gt;can_use_ipc_open3;
    return;
}

=head2 $bool = IPC::Cmd-&gt;can_use_run_forked

Utility function that tells you if C&lt;IPC::Cmd&gt; is capable of
providing C&lt;run_forked&gt; on the current platform.

=head1 FUNCTIONS

=head2 $path = can_run( PROGRAM );

C&lt;can_run&gt; takes only one argument: the name of a binary you wish
to locate. C&lt;can_run&gt; works much like the unix binary C&lt;which&gt; or the bash
command C&lt;type&gt;, which scans through your path, looking for the requested
binary.

Unlike C&lt;which&gt; and C&lt;type&gt;, this function is platform independent and
will also work on, for example, Win32.

If called in a scalar context it will return the full path to the binary
you asked for if it was found, or C&lt;undef&gt; if it was not.

If called in a list context and the global variable C&lt;$INSTANCES&gt; is a true
value, it will return a list of the full paths to instances
of the binary where found in C&lt;PATH&gt;, or an empty list if it was not found.

=cut

sub can_run {
    my $command = shift;

    # a lot of VMS executables have a symbol defined
    # check those first
    if ( $^O eq 'VMS' ) {
        require VMS::DCLsym;
        my $syms = VMS::DCLsym-&gt;new;
        return $command if scalar $syms-&gt;getsym( uc $command );
    }

    require File::Spec;
    require ExtUtils::MakeMaker;

    my @possibles;

    if( File::Spec-&gt;file_name_is_absolute($command) ) {
        return MM-&gt;maybe_command($command);

    } else {
        for my $dir (
            File::Spec-&gt;path,
            ( IS_WIN32 ? File::Spec-&gt;curdir : () )
        ) {
            next if ! $dir || ! -d $dir;
            my $abs = File::Spec-&gt;catfile( IS_WIN32 ? Win32::GetShortPathName( $dir ) : $dir, $command);
            push @possibles, $abs if $abs = MM-&gt;maybe_command($abs);
        }
    }
    return @possibles if wantarray and $INSTANCES;
    return shift @possibles;
}

=head2 $ok | ($ok, $err, $full_buf, $stdout_buff, $stderr_buff) = run( command =&gt; COMMAND, [verbose =&gt; BOOL, buffer =&gt; \$SCALAR, timeout =&gt; DIGIT] );

C&lt;run&gt; takes 4 arguments:

=over 4

=item command

This is the command to execute. It may be either a string or an array
reference.
This is a required argument.

See L&lt;"Caveats"&gt; for remarks on how commands are parsed and their
limitations.

=item verbose

This controls whether all output of a command should also be printed
to STDOUT/STDERR or should only be trapped in buffers (NOTE: buffers
require L&lt;IPC::Run&gt; to be installed, or your system able to work with
L&lt;IPC::Open3&gt;).

It will default to the global setting of C&lt;$IPC::Cmd::VERBOSE&gt;,
which by default is 0.

=item buffer

This will hold all the output of a command. It needs to be a reference
to a scalar.
Note that this will hold both the STDOUT and STDERR messages, and you
have no way of telling which is which.
If you require this distinction, run the C&lt;run&gt; command in list context
and inspect the individual buffers.

Of course, this requires that the underlying call supports buffers. See
the note on buffers above.

=item timeout

Sets the maximum time the command is allowed to run before aborting,
using the built-in C&lt;alarm()&gt; call. If the timeout is triggered, the
C&lt;errorcode&gt; in the return value will be set to an object of the
C&lt;IPC::Cmd::TimeOut&gt; class. See the L&lt;"error message"&gt; section below for
details.

Defaults to C&lt;0&gt;, meaning no timeout is set.

=back

C&lt;run&gt; will return a simple C&lt;true&gt; or C&lt;false&gt; when called in scalar
context.
In list context, you will be returned a list of the following items:

=over 4

=item success

A simple boolean indicating if the command executed without errors or
not.

=item error message

If the first element of the return value (C&lt;success&gt;) was 0, then some
error occurred. This second element is the error message the command
you requested exited with, if available. This is generally a pretty
printed value of C&lt;$?&gt; or C&lt;$@&gt;. See C&lt;perldoc perlvar&gt; for details on
what they can contain.
If the error was a timeout, the C&lt;error message&gt; will be prefixed with
the string C&lt;IPC::Cmd::TimeOut&gt;, the timeout class.

=item full_buffer

This is an array reference containing all the output the command
generated.
Note that buffers are only available if you have L&lt;IPC::Run&gt; installed,
or if your system is able to work with L&lt;IPC::Open3&gt; -- see below).
Otherwise, this element will be C&lt;undef&gt;.

=item out_buffer

This is an array reference containing all the output sent to STDOUT the
command generated. The notes from L&lt;"full_buffer"&gt; apply.

=item error_buffer

This is an arrayreference containing all the output sent to STDERR the
command generated. The notes from L&lt;"full_buffer"&gt; apply.


=back

See the L&lt;"HOW IT WORKS"&gt; section below to see how C&lt;IPC::Cmd&gt; decides
what modules or function calls to use when issuing a command.

=cut

{   my @acc = qw[ok error _fds];

    ### autogenerate accessors ###
    for my $key ( @acc ) {
        no strict 'refs';
        *{__PACKAGE__."::$key"} = sub {
            $_[0]-&gt;{$key} = $_[1] if @_ &gt; 1;
            return $_[0]-&gt;{$key};
        }
    }
}

sub can_use_run_forked {
    return $CAN_USE_RUN_FORKED eq "1";
}

sub get_monotonic_time {
    if ($HAVE_MONOTONIC) {
        return Time::HiRes::clock_gettime(&amp;Time::HiRes::CLOCK_MONOTONIC);
    }
    else {
        return time();
    }
}

sub adjust_monotonic_start_time {
    my ($ref_vars, $now, $previous) = @_;

    # workaround only for those systems which don't have
    # Time::HiRes::CLOCK_MONOTONIC (Mac OSX in particular)
    return if $HAVE_MONOTONIC;

    # don't have previous monotonic value (only happens once
    # in the beginning of the program execution)
    return unless $previous;

    my $time_diff = $now - $previous;

    # adjust previously saved time with the skew value which is
    # either negative when clock moved back or more than 5 seconds --
    # assuming that event loop does happen more often than once
    # per five seconds, which might not be always true (!) but
    # hopefully that's ok, because it's just a workaround
    if ($time_diff &gt; 5 || $time_diff &lt; 0) {
        foreach my $ref_var (@{$ref_vars}) {
            if (defined($$ref_var)) {
                $$ref_var = $$ref_var + $time_diff;
            }
        }
    }
}

sub uninstall_signals {
		return unless defined($IPC::Cmd::{'__old_signals'});

		foreach my $sig_name (keys %{$IPC::Cmd::{'__old_signals'}}) {
				$SIG{$sig_name} = $IPC::Cmd::{'__old_signals'}-&gt;{$sig_name};
		}
}

# incompatible with POSIX::SigAction
#
sub install_layered_signal {
  my ($s, $handler_code) = @_;

  my %available_signals = map {$_ =&gt; 1} keys %SIG;

  Carp::confess("install_layered_signal got nonexistent signal name [$s]")
    unless defined($available_signals{$s});
  Carp::confess("install_layered_signal expects coderef")
    if !ref($handler_code) || ref($handler_code) ne 'CODE';

  $IPC::Cmd::{'__old_signals'} = {}
  		unless defined($IPC::Cmd::{'__old_signals'});
	$IPC::Cmd::{'__old_signals'}-&gt;{$s} = $SIG{$s};

  my $previous_handler = $SIG{$s};

  my $sig_handler = sub {
    my ($called_sig_name, @sig_param) = @_;

    # $s is a closure referring to real signal name
    # for which this handler is being installed.
    # it is used to distinguish between
    # real signal handlers and aliased signal handlers
    my $signal_name = $s;

    # $called_sig_name is a signal name which
    # was passed to this signal handler;
    # it doesn't equal $signal_name in case
    # some signal handlers in %SIG point
    # to other signal handler (CHLD and CLD,
    # ABRT and IOT)
    #
    # initial signal handler for aliased signal
    # calls some other signal handler which
    # should not execute the same handler_code again
    if ($called_sig_name eq $signal_name) {
      $handler_code-&gt;($signal_name);
    }

    # run original signal handler if any (including aliased)
    #
    if (ref($previous_handler)) {
      $previous_handler-&gt;($called_sig_name, @sig_param);
    }
  };

  $SIG{$s} = $sig_handler;
}

# give process a chance sending TERM,
# waiting for a while (2 seconds)
# and killing it with KILL
sub kill_gently {
  my ($pid, $opts) = @_;

  require POSIX;

  $opts = {} unless $opts;
  $opts-&gt;{'wait_time'} = 2 unless defined($opts-&gt;{'wait_time'});
  $opts-&gt;{'first_kill_type'} = 'just_process' unless $opts-&gt;{'first_kill_type'};
  $opts-&gt;{'final_kill_type'} = 'just_process' unless $opts-&gt;{'final_kill_type'};

  if ($opts-&gt;{'first_kill_type'} eq 'just_process') {
    kill(15, $pid);
  }
  elsif ($opts-&gt;{'first_kill_type'} eq 'process_group') {
    kill(-15, $pid);
  }

  my $do_wait = 1;
  my $child_finished = 0;

  my $wait_start_time = get_monotonic_time();
  my $now;
  my $previous_monotonic_value;

  while ($do_wait) {
    $previous_monotonic_value = $now;
    $now = get_monotonic_time();
    
    adjust_monotonic_start_time([\$wait_start_time], $now, $previous_monotonic_value);

    if ($now &gt; $wait_start_time + $opts-&gt;{'wait_time'}) {
        $do_wait = 0;
        next;
    }

    my $waitpid = waitpid($pid, POSIX::WNOHANG);

    if ($waitpid eq -1) {
        $child_finished = 1;
        $do_wait = 0;
        next;
    }
    
    Time::HiRes::usleep(250000); # quarter of a second
  }

  if (!$child_finished) {
    if ($opts-&gt;{'final_kill_type'} eq 'just_process') {
      kill(9, $pid);
    }
    elsif ($opts-&gt;{'final_kill_type'} eq 'process_group') {
      kill(-9, $pid);
    }
  }
}

sub open3_run {
    my ($cmd, $opts) = @_;

    $opts = {} unless $opts;

    my $child_in = FileHandle-&gt;new;
    my $child_out = FileHandle-&gt;new;
    my $child_err = FileHandle-&gt;new;
    $child_out-&gt;autoflush(1);
    $child_err-&gt;autoflush(1);

    my $pid = open3($child_in, $child_out, $child_err, $cmd);
    Time::HiRes::usleep(1);

    # push my child's pid to our parent
    # so in case i am killed parent
    # could stop my child (search for
    # child_child_pid in parent code)
    if ($opts-&gt;{'parent_info'}) {
      my $ps = $opts-&gt;{'parent_info'};
      print $ps "spawned $pid\n";
    }

    if ($child_in &amp;&amp; $child_out-&gt;opened &amp;&amp; $opts-&gt;{'child_stdin'}) {
        # If the child process dies for any reason,
        # the next write to CHLD_IN is likely to generate
        # a SIGPIPE in the parent, which is fatal by default.
        # So you may wish to handle this signal.
        #
        # from http://perldoc.perl.org/IPC/Open3.html,
        # absolutely needed to catch piped commands errors.
        #
        local $SIG{'PIPE'} = sub { 1; };

        print $child_in $opts-&gt;{'child_stdin'};
    }
    close($child_in);

    my $child_output = {
        'out' =&gt; $child_out-&gt;fileno,
        'err' =&gt; $child_err-&gt;fileno,
        $child_out-&gt;fileno =&gt; {
            'parent_socket' =&gt; $opts-&gt;{'parent_stdout'},
            'scalar_buffer' =&gt; "",
            'child_handle' =&gt; $child_out,
            'block_size' =&gt; ($child_out-&gt;stat)[11] || 1024,
          },
        $child_err-&gt;fileno =&gt; {
            'parent_socket' =&gt; $opts-&gt;{'parent_stderr'},
            'scalar_buffer' =&gt; "",
            'child_handle' =&gt; $child_err,
            'block_size' =&gt; ($child_err-&gt;stat)[11] || 1024,
          },
        };

    my $select = IO::Select-&gt;new();
    $select-&gt;add($child_out, $child_err);

    # pass any signal to the child
    # effectively creating process
    # strongly attached to the child:
    # it will terminate only after child
    # has terminated (except for SIGKILL,
    # which is specially handled)
    SIGNAL: foreach my $s (keys %SIG) {
        next SIGNAL if $s eq '__WARN__' or $s eq '__DIE__'; # Skip and don't clobber __DIE__ &amp; __WARN__
        my $sig_handler;
        $sig_handler = sub {
            kill("$s", $pid);
            $SIG{$s} = $sig_handler;
        };
        $SIG{$s} = $sig_handler;
    }

    my $child_finished = 0;

    my $real_exit;
    my $exit_value;

    while(!$child_finished) {

        # parent was killed otherwise we would have got
        # the same signal as parent and process it same way
        if (getppid() eq "1") {

          # end my process group with all the children
          # (i am the process group leader, so my pid
          # equals to the process group id)
          #
          # same thing which is done
          # with $opts-&gt;{'clean_up_children'}
          # in run_forked
          #
          kill(-9, $$);

          POSIX::_exit 1;
        }

        my $waitpid = waitpid($pid, POSIX::WNOHANG);

        # child finished, catch it's exit status
        if ($waitpid ne 0 &amp;&amp; $waitpid ne -1) {
          $real_exit = $?;
          $exit_value = $? &gt;&gt; 8;
        }

        if ($waitpid eq -1) {
          $child_finished = 1;
        }


        my $ready_fds = [];
        push @{$ready_fds}, $select-&gt;can_read(1/100);

        READY_FDS: while (scalar(@{$ready_fds})) {
            my $fd = shift @{$ready_fds};
            $ready_fds = [grep {$_ ne $fd} @{$ready_fds}];

            my $str = $child_output-&gt;{$fd-&gt;fileno};
            Carp::confess("child stream not found: $fd") unless $str;

            my $data;
            my $count = $fd-&gt;sysread($data, $str-&gt;{'block_size'});

            if ($count) {
                if ($str-&gt;{'parent_socket'}) {
                    my $ph = $str-&gt;{'parent_socket'};
                    print $ph $data;
                }
                else {
                    $str-&gt;{'scalar_buffer'} .= $data;
                }
            }
            elsif ($count eq 0) {
                $select-&gt;remove($fd);
                $fd-&gt;close();
            }
            else {
                Carp::confess("error during sysread: " . $!);
            }

            push @{$ready_fds}, $select-&gt;can_read(1/100) if $child_finished;
        }

        Time::HiRes::usleep(1);
    }

    # since we've successfully reaped the child,
    # let our parent know about this.
    #
    if ($opts-&gt;{'parent_info'}) {
        my $ps = $opts-&gt;{'parent_info'};

        # child was killed, inform parent
        if ($real_exit &amp; 127) {
          print $ps "$pid killed with " . ($real_exit &amp; 127) . "\n";
        }

        print $ps "reaped $pid\n";
    }

    if ($opts-&gt;{'parent_stdout'} || $opts-&gt;{'parent_stderr'}) {
        return $exit_value;
    }
    else {
        return {
            'stdout' =&gt; $child_output-&gt;{$child_output-&gt;{'out'}}-&gt;{'scalar_buffer'},
            'stderr' =&gt; $child_output-&gt;{$child_output-&gt;{'err'}}-&gt;{'scalar_buffer'},
            'exit_code' =&gt; $exit_value,
            };
    }
}

=head2 $hashref = run_forked( COMMAND, { child_stdin =&gt; SCALAR, timeout =&gt; DIGIT, stdout_handler =&gt; CODEREF, stderr_handler =&gt; CODEREF} );

C&lt;run_forked&gt; is used to execute some program or a coderef,
optionally feed it with some input, get its return code
and output (both stdout and stderr into separate buffers).
In addition, it allows to terminate the program
if it takes too long to finish.

The important and distinguishing feature of run_forked
is execution timeout which at first seems to be
quite a simple task but if you think
that the program which you're spawning
might spawn some children itself (which
in their turn could do the same and so on)
it turns out to be not a simple issue.

C&lt;run_forked&gt; is designed to survive and
successfully terminate almost any long running task,
even a fork bomb in case your system has the resources
to survive during given timeout.

This is achieved by creating separate watchdog process
which spawns the specified program in a separate
process session and supervises it: optionally
feeds it with input, stores its exit code,
stdout and stderr, terminates it in case
it runs longer than specified.

Invocation requires the command to be executed or a coderef and optionally a hashref of options:

=over

=item C&lt;timeout&gt;

Specify in seconds how long to run the command before it is killed with SIG_KILL (9),
which effectively terminates it and all of its children (direct or indirect).

=item C&lt;child_stdin&gt;

Specify some text that will be passed into the C&lt;STDIN&gt; of the executed program.

=item C&lt;stdout_handler&gt;

Coderef of a subroutine to call when a portion of data is received on
STDOUT from the executing program.

=item C&lt;stderr_handler&gt;

Coderef of a subroutine to call when a portion of data is received on
STDERR from the executing program.

=item C&lt;wait_loop_callback&gt;

Coderef of a subroutine to call inside of the main waiting loop
(while C&lt;run_forked&gt; waits for the external to finish or fail).
It is useful to stop running external process before it ends
by itself, e.g.

  my $r = run_forked("some external command", {
	  'wait_loop_callback' =&gt; sub {
          if (condition) {
              kill(1, $$);
          }
	  },
	  'terminate_on_signal' =&gt; 'HUP',
	  });

Combined with C&lt;stdout_handler&gt; and C&lt;stderr_handler&gt; allows terminating
external command based on its output. Could also be used as a timer
without engaging with L&lt;alarm&gt; (signals).

Remember that this code could be called every millisecond (depending
on the output which external command generates), so try to make it
as lightweight as possible.

=item C&lt;discard_output&gt;

Discards the buffering of the standard output and standard errors for return by run_forked().
With this option you have to use the std*_handlers to read what the command outputs.
Useful for commands that send a lot of output.

=item C&lt;terminate_on_parent_sudden_death&gt;

Enable this option if you wish all spawned processes to be killed if the initially spawned
process (the parent) is killed or dies without waiting for child processes.

=back

C&lt;run_forked&gt; will return a HASHREF with the following keys:

=over

=item C&lt;exit_code&gt;

The exit code of the executed program.

=item C&lt;timeout&gt;

The number of seconds the program ran for before being terminated, or 0 if no timeout occurred.

=item C&lt;stdout&gt;

Holds the standard output of the executed command (or empty string if
there was no STDOUT output or if C&lt;discard_output&gt; was used; it's always defined!)

=item C&lt;stderr&gt;

Holds the standard error of the executed command (or empty string if
there was no STDERR output or if C&lt;discard_output&gt; was used; it's always defined!)

=item C&lt;merged&gt;

Holds the standard output and error of the executed command merged into one stream
(or empty string if there was no output at all or if C&lt;discard_output&gt; was used; it's always defined!)

=item C&lt;err_msg&gt;

Holds some explanation in the case of an error.

=back

=cut

sub run_forked {
    ### container to store things in
    my $self = bless {}, __PACKAGE__;

    if (!can_use_run_forked()) {
        Carp::carp("run_forked is not available: $CAN_USE_RUN_FORKED");
        return;
    }

    require POSIX;

    my ($cmd, $opts) = @_;
    if (ref($cmd) eq 'ARRAY') {
        $cmd = join(" ", @{$cmd});
    }

    if (!$cmd) {
        Carp::carp("run_forked expects command to run");
        return;
    }

    $opts = {} unless $opts;
    $opts-&gt;{'timeout'} = 0 unless $opts-&gt;{'timeout'};
    $opts-&gt;{'terminate_wait_time'} = 2 unless defined($opts-&gt;{'terminate_wait_time'});

    # turned on by default
    $opts-&gt;{'clean_up_children'} = 1 unless defined($opts-&gt;{'clean_up_children'});

    # sockets to pass child stdout to parent
    my $child_stdout_socket;
    my $parent_stdout_socket;

    # sockets to pass child stderr to parent
    my $child_stderr_socket;
    my $parent_stderr_socket;

    # sockets for child -&gt; parent internal communication
    my $child_info_socket;
    my $parent_info_socket;

    socketpair($child_stdout_socket, $parent_stdout_socket, &amp;Socket::AF_UNIX, &amp;Socket::SOCK_STREAM, &amp;Socket::PF_UNSPEC) ||
      Carp::confess ("socketpair: $!");
    socketpair($child_stderr_socket, $parent_stderr_socket, &amp;Socket::AF_UNIX, &amp;Socket::SOCK_STREAM, &amp;Socket::PF_UNSPEC) ||
      Carp::confess ("socketpair: $!");
    socketpair($child_info_socket, $parent_info_socket, &amp;Socket::AF_UNIX, &amp;Socket::SOCK_STREAM, &amp;Socket::PF_UNSPEC) ||
      Carp::confess ("socketpair: $!");

    $child_stdout_socket-&gt;autoflush(1);
    $parent_stdout_socket-&gt;autoflush(1);
    $child_stderr_socket-&gt;autoflush(1);
    $parent_stderr_socket-&gt;autoflush(1);
    $child_info_socket-&gt;autoflush(1);
    $parent_info_socket-&gt;autoflush(1);

    my $start_time = get_monotonic_time();

    my $pid;
    if ($pid = fork) {

      # we are a parent
      close($parent_stdout_socket);
      close($parent_stderr_socket);
      close($parent_info_socket);

      my $flags;

      # prepare sockets to read from child

      $flags = fcntl($child_stdout_socket, POSIX::F_GETFL, 0) || Carp::confess "can't fnctl F_GETFL: $!";
      $flags |= POSIX::O_NONBLOCK;
      fcntl($child_stdout_socket, POSIX::F_SETFL, $flags) || Carp::confess "can't fnctl F_SETFL: $!";

      $flags = fcntl($child_stderr_socket, POSIX::F_GETFL, 0) || Carp::confess "can't fnctl F_GETFL: $!";
      $flags |= POSIX::O_NONBLOCK;
      fcntl($child_stderr_socket, POSIX::F_SETFL, $flags) || Carp::confess "can't fnctl F_SETFL: $!";

      $flags = fcntl($child_info_socket, POSIX::F_GETFL, 0) || Carp::confess "can't fnctl F_GETFL: $!";
      $flags |= POSIX::O_NONBLOCK;
      fcntl($child_info_socket, POSIX::F_SETFL, $flags) || Carp::confess "can't fnctl F_SETFL: $!";

  #    print "child $pid started\n";

      my $child_output = {
        $child_stdout_socket-&gt;fileno =&gt; {
          'scalar_buffer' =&gt; "",
          'child_handle' =&gt; $child_stdout_socket,
          'block_size' =&gt; ($child_stdout_socket-&gt;stat)[11] || 1024,
          'protocol' =&gt; 'stdout',
          },
        $child_stderr_socket-&gt;fileno =&gt; {
          'scalar_buffer' =&gt; "",
          'child_handle' =&gt; $child_stderr_socket,
          'block_size' =&gt; ($child_stderr_socket-&gt;stat)[11] || 1024,
          'protocol' =&gt; 'stderr',
          },
        $child_info_socket-&gt;fileno =&gt; {
          'scalar_buffer' =&gt; "",
          'child_handle' =&gt; $child_info_socket,
          'block_size' =&gt; ($child_info_socket-&gt;stat)[11] || 1024,
          'protocol' =&gt; 'info',
          },
        };

      my $select = IO::Select-&gt;new();
      $select-&gt;add($child_stdout_socket, $child_stderr_socket, $child_info_socket);

      my $child_timedout = 0;
      my $child_finished = 0;
      my $child_stdout = '';
      my $child_stderr = '';
      my $child_merged = '';
      my $child_exit_code = 0;
      my $child_killed_by_signal = 0;
      my $parent_died = 0;

      my $last_parent_check = 0;
      my $got_sig_child = 0;
      my $got_sig_quit = 0;
      my $orig_sig_child = $SIG{'CHLD'};

      $SIG{'CHLD'} = sub { $got_sig_child = get_monotonic_time(); };

      if ($opts-&gt;{'terminate_on_signal'}) {
        install_layered_signal($opts-&gt;{'terminate_on_signal'}, sub { $got_sig_quit = time(); });
      }

      my $child_child_pid;
      my $now;
      my $previous_monotonic_value;

      while (!$child_finished) {
        $previous_monotonic_value = $now;
        $now = get_monotonic_time();

        adjust_monotonic_start_time([\$start_time, \$last_parent_check, \$got_sig_child], $now, $previous_monotonic_value);

        if ($opts-&gt;{'terminate_on_parent_sudden_death'}) {
          # check for parent once each five seconds
          if ($now &gt; $last_parent_check + 5) {
            if (getppid() eq "1") {
              kill_gently ($pid, {
                'first_kill_type' =&gt; 'process_group',
                'final_kill_type' =&gt; 'process_group',
                'wait_time' =&gt; $opts-&gt;{'terminate_wait_time'}
                });
              $parent_died = 1;
            }

            $last_parent_check = $now;
          }
        }

        # user specified timeout
        if ($opts-&gt;{'timeout'}) {
          if ($now &gt; $start_time + $opts-&gt;{'timeout'}) {
            kill_gently ($pid, {
              'first_kill_type' =&gt; 'process_group',
              'final_kill_type' =&gt; 'process_group',
              'wait_time' =&gt; $opts-&gt;{'terminate_wait_time'}
              });
            $child_timedout = 1;
          }
        }

        # give OS 10 seconds for correct return of waitpid,
        # kill process after that and finish wait loop;
        # shouldn't ever happen -- remove this code?
        if ($got_sig_child) {
          if ($now &gt; $got_sig_child + 10) {
            print STDERR "waitpid did not return -1 for 10 seconds after SIG_CHLD, killing [$pid]\n";
            kill (-9, $pid);
            $child_finished = 1;
          }
        }

        if ($got_sig_quit) {
          kill_gently ($pid, {
            'first_kill_type' =&gt; 'process_group',
            'final_kill_type' =&gt; 'process_group',
            'wait_time' =&gt; $opts-&gt;{'terminate_wait_time'}
            });
          $child_finished = 1;
        }

        my $waitpid = waitpid($pid, POSIX::WNOHANG);

        # child finished, catch it's exit status
        if ($waitpid ne 0 &amp;&amp; $waitpid ne -1) {
          $child_exit_code = $? &gt;&gt; 8;
        }

        if ($waitpid eq -1) {
          $child_finished = 1;
        }

        my $ready_fds = [];
        push @{$ready_fds}, $select-&gt;can_read(1/100);

        READY_FDS: while (scalar(@{$ready_fds})) {
          my $fd = shift @{$ready_fds};
          $ready_fds = [grep {$_ ne $fd} @{$ready_fds}];

          my $str = $child_output-&gt;{$fd-&gt;fileno};
          Carp::confess("child stream not found: $fd") unless $str;

          my $data = "";
          my $count = $fd-&gt;sysread($data, $str-&gt;{'block_size'});

          if ($count) {
              # extract all the available lines and store the rest in temporary buffer
              if ($data =~ /(.+\n)([^\n]*)/so) {
                  $data = $str-&gt;{'scalar_buffer'} . $1;
                  $str-&gt;{'scalar_buffer'} = $2 || "";
              }
              else {
                  $str-&gt;{'scalar_buffer'} .= $data;
                  $data = "";
              }
          }
          elsif ($count eq 0) {
            $select-&gt;remove($fd);
            $fd-&gt;close();
            if ($str-&gt;{'scalar_buffer'}) {
                $data = $str-&gt;{'scalar_buffer'} . "\n";
            }
          }
          else {
            Carp::confess("error during sysread on [$fd]: " . $!);
          }

          # $data contains only full lines (or last line if it was unfinished read
          # or now new-line in the output of the child); dat is processed
          # according to the "protocol" of socket
          if ($str-&gt;{'protocol'} eq 'info') {
            if ($data =~ /^spawned ([0-9]+?)\n(.*?)/so) {
              $child_child_pid = $1;
              $data = $2;
            }
            if ($data =~ /^reaped ([0-9]+?)\n(.*?)/so) {
              $child_child_pid = undef;
              $data = $2;
            }
            if ($data =~ /^[\d]+ killed with ([0-9]+?)\n(.*?)/so) {
              $child_killed_by_signal = $1;
              $data = $2;
            }

            # we don't expect any other data in info socket, so it's
            # some strange violation of protocol, better know about this
            if ($data) {
              Carp::confess("info protocol violation: [$data]");
            }
          }
          if ($str-&gt;{'protocol'} eq 'stdout') {
            if (!$opts-&gt;{'discard_output'}) {
              $child_stdout .= $data;
              $child_merged .= $data;
            }

            if ($opts-&gt;{'stdout_handler'} &amp;&amp; ref($opts-&gt;{'stdout_handler'}) eq 'CODE') {
              $opts-&gt;{'stdout_handler'}-&gt;($data);
            }
          }
          if ($str-&gt;{'protocol'} eq 'stderr') {
            if (!$opts-&gt;{'discard_output'}) {
              $child_stderr .= $data;
              $child_merged .= $data;
            }

            if ($opts-&gt;{'stderr_handler'} &amp;&amp; ref($opts-&gt;{'stderr_handler'}) eq 'CODE') {
              $opts-&gt;{'stderr_handler'}-&gt;($data);
            }
          }
 
          # process may finish (waitpid returns -1) before
          # we've read all of its output because of buffering;
          # so try to read all the way it is possible to read
          # in such case - this shouldn't be too much (unless
          # the buffer size is HUGE -- should introduce
          # another counter in such case, maybe later)
          #
          push @{$ready_fds}, $select-&gt;can_read(1/100) if $child_finished;
        }

        if ($opts-&gt;{'wait_loop_callback'} &amp;&amp; ref($opts-&gt;{'wait_loop_callback'}) eq 'CODE') {
          $opts-&gt;{'wait_loop_callback'}-&gt;();
        }

        Time::HiRes::usleep(1);
      }

      # $child_pid_pid is not defined in two cases:
      #  * when our child was killed before
      #    it had chance to tell us the pid
      #    of the child it spawned. we can do
      #    nothing in this case :(
      #  * our child successfully reaped its child,
      #    we have nothing left to do in this case
      #
      # defined $child_pid_pid means child's child
      # has not died but nobody is waiting for it,
      # killing it brutally.
      #
      if ($child_child_pid) {
        kill_gently($child_child_pid);
      }

      # in case there are forks in child which
      # do not forward or process signals (TERM) correctly
      # kill whole child process group, effectively trying
      # not to return with some children or their parts still running
      #
      # to be more accurate -- we need to be sure
      # that this is process group created by our child
      # (and not some other process group with the same pgid,
      # created just after death of our child) -- fortunately
      # this might happen only when process group ids
      # are reused quickly (there are lots of processes
      # spawning new process groups for example)
      #
      if ($opts-&gt;{'clean_up_children'}) {
        kill(-9, $pid);
      }

  #    print "child $pid finished\n";

      close($child_stdout_socket);
      close($child_stderr_socket);
      close($child_info_socket);

      my $o = {
        'stdout' =&gt; $child_stdout,
        'stderr' =&gt; $child_stderr,
        'merged' =&gt; $child_merged,
        'timeout' =&gt; $child_timedout ? $opts-&gt;{'timeout'} : 0,
        'exit_code' =&gt; $child_exit_code,
        'parent_died' =&gt; $parent_died,
        'killed_by_signal' =&gt; $child_killed_by_signal,
        'child_pgid' =&gt; $pid,
        'cmd' =&gt; $cmd,
        };

      my $err_msg = '';
      if ($o-&gt;{'exit_code'}) {
        $err_msg .= "exited with code [$o-&gt;{'exit_code'}]\n";
      }
      if ($o-&gt;{'timeout'}) {
        $err_msg .= "ran more than [$o-&gt;{'timeout'}] seconds\n";
      }
      if ($o-&gt;{'parent_died'}) {
        $err_msg .= "parent died\n";
      }
      if ($o-&gt;{'stdout'} &amp;&amp; !$opts-&gt;{'non_empty_stdout_ok'}) {
        $err_msg .= "stdout:\n" . $o-&gt;{'stdout'} . "\n";
      }
      if ($o-&gt;{'stderr'}) {
        $err_msg .= "stderr:\n" . $o-&gt;{'stderr'} . "\n";
      }
      if ($o-&gt;{'killed_by_signal'}) {
        $err_msg .= "killed by signal [" . $o-&gt;{'killed_by_signal'} . "]\n";
      }
      $o-&gt;{'err_msg'} = $err_msg;

      if ($orig_sig_child) {
        $SIG{'CHLD'} = $orig_sig_child;
      }
      else {
        delete($SIG{'CHLD'});
      }

      uninstall_signals();

      return $o;
    }
    else {
      Carp::confess("cannot fork: $!") unless defined($pid);

      # create new process session for open3 call,
      # so we hopefully can kill all the subprocesses
      # which might be spawned in it (except for those
      # which do setsid theirselves -- can't do anything
      # with those)

      POSIX::setsid() || Carp::confess("Error running setsid: " . $!);

      if ($opts-&gt;{'child_BEGIN'} &amp;&amp; ref($opts-&gt;{'child_BEGIN'}) eq 'CODE') {
        $opts-&gt;{'child_BEGIN'}-&gt;();
      }

      close($child_stdout_socket);
      close($child_stderr_socket);
      close($child_info_socket);

      my $child_exit_code;

      # allow both external programs
      # and internal perl calls
      if (!ref($cmd)) {
        $child_exit_code = open3_run($cmd, {
          'parent_info' =&gt; $parent_info_socket,
          'parent_stdout' =&gt; $parent_stdout_socket,
          'parent_stderr' =&gt; $parent_stderr_socket,
          'child_stdin' =&gt; $opts-&gt;{'child_stdin'},
          });
      }
      elsif (ref($cmd) eq 'CODE') {
        # reopen STDOUT and STDERR for child code:
        # https://rt.cpan.org/Ticket/Display.html?id=85912
        open STDOUT, '&gt;&amp;', $parent_stdout_socket || Carp::confess("Unable to reopen STDOUT: $!\n");
        open STDERR, '&gt;&amp;', $parent_stderr_socket || Carp::confess("Unable to reopen STDERR: $!\n");

        $child_exit_code = $cmd-&gt;({
          'opts' =&gt; $opts,
          'parent_info' =&gt; $parent_info_socket,
          'parent_stdout' =&gt; $parent_stdout_socket,
          'parent_stderr' =&gt; $parent_stderr_socket,
          'child_stdin' =&gt; $opts-&gt;{'child_stdin'},
          });
      }
      else {
        print $parent_stderr_socket "Invalid command reference: " . ref($cmd) . "\n";
        $child_exit_code = 1;
      }

      close($parent_stdout_socket);
      close($parent_stderr_socket);
      close($parent_info_socket);

      if ($opts-&gt;{'child_END'} &amp;&amp; ref($opts-&gt;{'child_END'}) eq 'CODE') {
        $opts-&gt;{'child_END'}-&gt;();
      }

      $| = 1;
      POSIX::_exit $child_exit_code;
    }
}

sub run {
    ### container to store things in
    my $self = bless {}, __PACKAGE__;

    my %hash = @_;

    ### if the user didn't provide a buffer, we'll store it here.
    my $def_buf = '';

    my($verbose,$cmd,$buffer,$timeout);
    my $tmpl = {
        verbose =&gt; { default  =&gt; $VERBOSE,  store =&gt; \$verbose },
        buffer  =&gt; { default  =&gt; \$def_buf, store =&gt; \$buffer },
        command =&gt; { required =&gt; 1,         store =&gt; \$cmd,
                     allow    =&gt; sub { !ref($_[0]) or ref($_[0]) eq 'ARRAY' },
        },
        timeout =&gt; { default  =&gt; 0,         store =&gt; \$timeout },
    };

    unless( check( $tmpl, \%hash, $VERBOSE ) ) {
        Carp::carp( loc( "Could not validate input: %1",
                         Params::Check-&gt;last_error ) );
        return;
    };

    $cmd = _quote_args_vms( $cmd ) if IS_VMS;

    ### strip any empty elements from $cmd if present
    if ( $ALLOW_NULL_ARGS ) {
      $cmd = [ grep { defined } @$cmd ] if ref $cmd;
    }
    else {
      $cmd = [ grep { defined &amp;&amp; length } @$cmd ] if ref $cmd;
    }

    my $pp_cmd = (ref $cmd ? "@$cmd" : $cmd);
    print loc("Running [%1]...\n", $pp_cmd ) if $verbose;

    ### did the user pass us a buffer to fill or not? if so, set this
    ### flag so we know what is expected of us
    ### XXX this is now being ignored. in the future, we could add diagnostic
    ### messages based on this logic
    #my $user_provided_buffer = $buffer == \$def_buf ? 0 : 1;

    ### buffers that are to be captured
    my( @buffer, @buff_err, @buff_out );

    ### capture STDOUT
    my $_out_handler = sub {
        my $buf = shift;
        return unless defined $buf;

        print STDOUT $buf if $verbose;
        push @buffer,   $buf;
        push @buff_out, $buf;
    };

    ### capture STDERR
    my $_err_handler = sub {
        my $buf = shift;
        return unless defined $buf;

        print STDERR $buf if $verbose;
        push @buffer,   $buf;
        push @buff_err, $buf;
    };


    ### flag to indicate we have a buffer captured
    my $have_buffer = $self-&gt;can_capture_buffer ? 1 : 0;

    ### flag indicating if the subcall went ok
    my $ok;

    ### don't look at previous errors:
    local $?;
    local $@;
    local $!;

    ### we might be having a timeout set
    eval {
        local $SIG{ALRM} = sub { die bless sub {
            ALARM_CLASS .
            qq[: Command '$pp_cmd' aborted by alarm after $timeout seconds]
        }, ALARM_CLASS } if $timeout;
        alarm $timeout || 0;

        ### IPC::Run is first choice if $USE_IPC_RUN is set.
        if( !IS_WIN32 and $USE_IPC_RUN and $self-&gt;can_use_ipc_run( 1 ) ) {
            ### ipc::run handlers needs the command as a string or an array ref

            $self-&gt;_debug( "# Using IPC::Run. Have buffer: $have_buffer" )
                if $DEBUG;

            $ok = $self-&gt;_ipc_run( $cmd, $_out_handler, $_err_handler );

        ### since IPC::Open3 works on all platforms, and just fails on
        ### win32 for capturing buffers, do that ideally
        } elsif ( $USE_IPC_OPEN3 and $self-&gt;can_use_ipc_open3( 1 ) ) {

            $self-&gt;_debug("# Using IPC::Open3. Have buffer: $have_buffer")
                if $DEBUG;

            ### in case there are pipes in there;
            ### IPC::Open3 will call exec and exec will do the right thing

            my $method = IS_WIN32 ? '_open3_run_win32' : '_open3_run';

            $ok = $self-&gt;$method(
                                    $cmd, $_out_handler, $_err_handler, $verbose
                                );

        ### if we are allowed to run verbose, just dispatch the system command
        } else {
            $self-&gt;_debug( "# Using system(). Have buffer: $have_buffer" )
                if $DEBUG;
            $ok = $self-&gt;_system_run( $cmd, $verbose );
        }

        alarm 0;
    };

    ### restore STDIN after duping, or STDIN will be closed for
    ### this current perl process!
    $self-&gt;__reopen_fds( @{ $self-&gt;_fds} ) if $self-&gt;_fds;

    my $err;
    unless( $ok ) {
        ### alarm happened
        if ( $@ and ref $@ and $@-&gt;isa( ALARM_CLASS ) ) {
            $err = $@-&gt;();  # the error code is an expired alarm

        ### another error happened, set by the dispatchub
        } else {
            $err = $self-&gt;error;
        }
    }

    ### fill the buffer;
    $$buffer = join '', @buffer if @buffer;

    ### return a list of flags and buffers (if available) in list
    ### context, or just a simple 'ok' in scalar
    return wantarray
                ? $have_buffer
                    ? ($ok, $err, \@buffer, \@buff_out, \@buff_err)
                    : ($ok, $err )
                : $ok


}

sub _open3_run_win32 {
  my $self    = shift;
  my $cmd     = shift;
  my $outhand = shift;
  my $errhand = shift;

  require Socket;

  my $pipe = sub {
    socketpair($_[0], $_[1], &amp;Socket::AF_UNIX, &amp;Socket::SOCK_STREAM, &amp;Socket::PF_UNSPEC)
        or return undef;
    shutdown($_[0], 1);  # No more writing for reader
    shutdown($_[1], 0);  # No more reading for writer
    return 1;
  };

  my $open3 = sub {
    local (*TO_CHLD_R,     *TO_CHLD_W);
    local (*FR_CHLD_R,     *FR_CHLD_W);
    local (*FR_CHLD_ERR_R, *FR_CHLD_ERR_W);

    $pipe-&gt;(*TO_CHLD_R,     *TO_CHLD_W    ) or die $^E;
    $pipe-&gt;(*FR_CHLD_R,     *FR_CHLD_W    ) or die $^E;
    $pipe-&gt;(*FR_CHLD_ERR_R, *FR_CHLD_ERR_W) or die $^E;

    my $pid = IPC::Open3::open3('&gt;&amp;TO_CHLD_R', '&lt;&amp;FR_CHLD_W', '&lt;&amp;FR_CHLD_ERR_W', @_);

    return ( $pid, *TO_CHLD_W, *FR_CHLD_R, *FR_CHLD_ERR_R );
  };

  $cmd = [ grep { defined &amp;&amp; length } @$cmd ] if ref $cmd;
  $cmd = $self-&gt;__fix_cmd_whitespace_and_special_chars( $cmd );

  my ($pid, $to_chld, $fr_chld, $fr_chld_err) =
    $open3-&gt;( ( ref $cmd ? @$cmd : $cmd ) );

  my $in_sel  = IO::Select-&gt;new();
  my $out_sel = IO::Select-&gt;new();

  my %objs;

  $objs{ fileno( $fr_chld ) } = $outhand;
  $objs{ fileno( $fr_chld_err ) } = $errhand;
  $in_sel-&gt;add( $fr_chld );
  $in_sel-&gt;add( $fr_chld_err );

  close($to_chld);

  while ($in_sel-&gt;count() + $out_sel-&gt;count()) {
    my ($ins, $outs) = IO::Select::select($in_sel, $out_sel, undef);

    for my $fh (@$ins) {
        my $obj = $objs{ fileno($fh) };
        my $buf;
        my $bytes_read = sysread($fh, $buf, 64*1024 ); #, length($buf));
        if (!$bytes_read) {
            $in_sel-&gt;remove($fh);
        }
        else {
            $obj-&gt;( "$buf" );
        }
      }

      for my $fh (@$outs) {
      }
  }

  waitpid($pid, 0);

  ### some error occurred
  if( $? ) {
        $self-&gt;error( $self-&gt;_pp_child_error( $cmd, $? ) );
        $self-&gt;ok( 0 );
        return;
  } else {
        return $self-&gt;ok( 1 );
  }
}

sub _open3_run {
    my $self            = shift;
    my $cmd             = shift;
    my $_out_handler    = shift;
    my $_err_handler    = shift;
    my $verbose         = shift || 0;

    ### Following code are adapted from Friar 'abstracts' in the
    ### Perl Monastery (http://www.perlmonks.org/index.pl?node_id=151886).
    ### XXX that code didn't work.
    ### we now use the following code, thanks to theorbtwo

    ### define them beforehand, so we always have defined FH's
    ### to read from.
    use Symbol;
    my $kidout      = Symbol::gensym();
    my $kiderror    = Symbol::gensym();

    ### Dup the filehandle so we can pass 'our' STDIN to the
    ### child process. This stops us from having to pump input
    ### from ourselves to the childprocess. However, we will need
    ### to revive the FH afterwards, as IPC::Open3 closes it.
    ### We'll do the same for STDOUT and STDERR. It works without
    ### duping them on non-unix derivatives, but not on win32.
    my @fds_to_dup = ( IS_WIN32 &amp;&amp; !$verbose
                            ? qw[STDIN STDOUT STDERR]
                            : qw[STDIN]
                        );
    $self-&gt;_fds( \@fds_to_dup );
    $self-&gt;__dup_fds( @fds_to_dup );

    ### pipes have to come in a quoted string, and that clashes with
    ### whitespace. This sub fixes up such commands so they run properly
    $cmd = $self-&gt;__fix_cmd_whitespace_and_special_chars( $cmd );

    ### don't stringify @$cmd, so spaces in filenames/paths are
    ### treated properly
    my $pid = eval {
        IPC::Open3::open3(
                    '&lt;&amp;STDIN',
                    (IS_WIN32 ? '&gt;&amp;STDOUT' : $kidout),
                    (IS_WIN32 ? '&gt;&amp;STDERR' : $kiderror),
                    ( ref $cmd ? @$cmd : $cmd ),
                );
    };

    ### open3 error occurred
    if( $@ and $@ =~ /^open3:/ ) {
        $self-&gt;ok( 0 );
        $self-&gt;error( $@ );
        return;
    };

    ### use OUR stdin, not $kidin. Somehow,
    ### we never get the input.. so jump through
    ### some hoops to do it :(
    my $selector = IO::Select-&gt;new(
                        (IS_WIN32 ? \*STDERR : $kiderror),
                        \*STDIN,
                        (IS_WIN32 ? \*STDOUT : $kidout)
                    );

    STDOUT-&gt;autoflush(1);   STDERR-&gt;autoflush(1);   STDIN-&gt;autoflush(1);
    $kidout-&gt;autoflush(1)   if UNIVERSAL::can($kidout,   'autoflush');
    $kiderror-&gt;autoflush(1) if UNIVERSAL::can($kiderror, 'autoflush');

    ### add an explicit break statement
    ### code courtesy of theorbtwo from #london.pm
    my $stdout_done = 0;
    my $stderr_done = 0;
    OUTER: while ( my @ready = $selector-&gt;can_read ) {

        for my $h ( @ready ) {
            my $buf;

            ### $len is the amount of bytes read
            my $len = sysread( $h, $buf, 4096 );    # try to read 4096 bytes

            ### see perldoc -f sysread: it returns undef on error,
            ### so bail out.
            if( not defined $len ) {
                warn(loc("Error reading from process: %1", $!));
                last OUTER;
            }

            ### check for $len. it may be 0, at which point we're
            ### done reading, so don't try to process it.
            ### if we would print anyway, we'd provide bogus information
            $_out_handler-&gt;( "$buf" ) if $len &amp;&amp; $h == $kidout;
            $_err_handler-&gt;( "$buf" ) if $len &amp;&amp; $h == $kiderror;

            ### Wait till child process is done printing to both
            ### stdout and stderr.
            $stdout_done = 1 if $h == $kidout   and $len == 0;
            $stderr_done = 1 if $h == $kiderror and $len == 0;
            last OUTER if ($stdout_done &amp;&amp; $stderr_done);
        }
    }

    waitpid $pid, 0; # wait for it to die

    ### restore STDIN after duping, or STDIN will be closed for
    ### this current perl process!
    ### done in the parent call now
    # $self-&gt;__reopen_fds( @fds_to_dup );

    ### some error occurred
    if( $? ) {
        $self-&gt;error( $self-&gt;_pp_child_error( $cmd, $? ) );
        $self-&gt;ok( 0 );
        return;
    } else {
        return $self-&gt;ok( 1 );
    }
}

### Text::ParseWords::shellwords() uses unix semantics. that will break
### on win32
{   my $parse_sub = IS_WIN32
                        ? __PACKAGE__-&gt;can('_split_like_shell_win32')
                        : Text::ParseWords-&gt;can('shellwords');

    sub _ipc_run {
        my $self            = shift;
        my $cmd             = shift;
        my $_out_handler    = shift;
        my $_err_handler    = shift;

        STDOUT-&gt;autoflush(1); STDERR-&gt;autoflush(1);

        ### a command like:
        # [
        #     '/usr/bin/gzip',
        #     '-cdf',
        #     '/Users/kane/sources/p4/other/archive-extract/t/src/x.tgz',
        #     '|',
        #     '/usr/bin/tar',
        #     '-tf -'
        # ]
        ### needs to become:
        # [
        #     ['/usr/bin/gzip', '-cdf',
        #       '/Users/kane/sources/p4/other/archive-extract/t/src/x.tgz']
        #     '|',
        #     ['/usr/bin/tar', '-tf -']
        # ]


        my @command;
        my $special_chars;

        my $re = do { my $x = join '', SPECIAL_CHARS; qr/([$x])/ };
        if( ref $cmd ) {
            my $aref = [];
            for my $item (@$cmd) {
                if( $item =~ $re ) {
                    push @command, $aref, $item;
                    $aref = [];
                    $special_chars .= $1;
                } else {
                    push @$aref, $item;
                }
            }
            push @command, $aref;
        } else {
            @command = map { if( $_ =~ $re ) {
                                $special_chars .= $1; $_;
                             } else {
#                                [ split /\s+/ ]
                                 [ map { m/[ ]/ ? qq{'$_'} : $_ } $parse_sub-&gt;($_) ]
                             }
                        } split( /\s*$re\s*/, $cmd );
        }

        ### if there's a pipe in the command, *STDIN needs to
        ### be inserted *BEFORE* the pipe, to work on win32
        ### this also works on *nix, so we should do it when possible
        ### this should *also* work on multiple pipes in the command
        ### if there's no pipe in the command, append STDIN to the back
        ### of the command instead.
        ### XXX seems IPC::Run works it out for itself if you just
        ### don't pass STDIN at all.
        #     if( $special_chars and $special_chars =~ /\|/ ) {
        #         ### only add STDIN the first time..
        #         my $i;
        #         @command = map { ($_ eq '|' &amp;&amp; not $i++)
        #                             ? ( \*STDIN, $_ )
        #                             : $_
        #                         } @command;
        #     } else {
        #         push @command, \*STDIN;
        #     }

        # \*STDIN is already included in the @command, see a few lines up
        my $ok = eval { IPC::Run::run(   @command,
                                fileno(STDOUT).'&gt;',
                                $_out_handler,
                                fileno(STDERR).'&gt;',
                                $_err_handler
                            )
                        };

        ### all is well
        if( $ok ) {
            return $self-&gt;ok( $ok );

        ### some error occurred
        } else {
            $self-&gt;ok( 0 );

            ### if the eval fails due to an exception, deal with it
            ### unless it's an alarm
            if( $@ and not UNIVERSAL::isa( $@, ALARM_CLASS ) ) {
                $self-&gt;error( $@ );

            ### if it *is* an alarm, propagate
            } elsif( $@ ) {
                die $@;

            ### some error in the sub command
            } else {
                $self-&gt;error( $self-&gt;_pp_child_error( $cmd, $? ) );
            }

            return;
        }
    }
}

sub _system_run {
    my $self    = shift;
    my $cmd     = shift;
    my $verbose = shift || 0;

    ### pipes have to come in a quoted string, and that clashes with
    ### whitespace. This sub fixes up such commands so they run properly
    $cmd = $self-&gt;__fix_cmd_whitespace_and_special_chars( $cmd );

    my @fds_to_dup = $verbose ? () : qw[STDOUT STDERR];
    $self-&gt;_fds( \@fds_to_dup );
    $self-&gt;__dup_fds( @fds_to_dup );

    ### system returns 'true' on failure -- the exit code of the cmd
    $self-&gt;ok( 1 );
    system( ref $cmd ? @$cmd : $cmd ) == 0 or do {
        $self-&gt;error( $self-&gt;_pp_child_error( $cmd, $? ) );
        $self-&gt;ok( 0 );
    };

    ### done in the parent call now
    #$self-&gt;__reopen_fds( @fds_to_dup );

    return unless $self-&gt;ok;
    return $self-&gt;ok;
}

{   my %sc_lookup = map { $_ =&gt; $_ } SPECIAL_CHARS;


    sub __fix_cmd_whitespace_and_special_chars {
        my $self = shift;
        my $cmd  = shift;

        ### command has a special char in it
        if( ref $cmd and grep { $sc_lookup{$_} } @$cmd ) {

            ### since we have special chars, we have to quote white space
            ### this *may* conflict with the parsing :(
            my $fixed;
            my @cmd = map { / / ? do { $fixed++; QUOTE.$_.QUOTE } : $_ } @$cmd;

            $self-&gt;_debug( "# Quoted $fixed arguments containing whitespace" )
                    if $DEBUG &amp;&amp; $fixed;

            ### stringify it, so the special char isn't escaped as argument
            ### to the program
            $cmd = join ' ', @cmd;
        }

        return $cmd;
    }
}

### Command-line arguments (but not the command itself) must be quoted
### to ensure case preservation. Borrowed from Module::Build with adaptations.
### Patch for this supplied by Craig Berry, see RT #46288: [PATCH] Add argument
### quoting for run() on VMS
sub _quote_args_vms {
  ### Returns a command string with proper quoting so that the subprocess
  ### sees this same list of args, or if we get a single arg that is an
  ### array reference, quote the elements of it (except for the first)
  ### and return the reference.
  my @args = @_;
  my $got_arrayref = (scalar(@args) == 1
                      &amp;&amp; UNIVERSAL::isa($args[0], 'ARRAY'))
                   ? 1
                   : 0;

  @args = split(/\s+/, $args[0]) unless $got_arrayref || scalar(@args) &gt; 1;

  my $cmd = $got_arrayref ? shift @{$args[0]} : shift @args;

  ### Do not quote qualifiers that begin with '/' or previously quoted args.
  map { if (/^[^\/\"]/) {
          $_ =~ s/\"/""/g;     # escape C&lt;"&gt; by doubling
          $_ = q(").$_.q(");
        }
  }
    ($got_arrayref ? @{$args[0]}
                   : @args
    );

  $got_arrayref ? unshift(@{$args[0]}, $cmd) : unshift(@args, $cmd);

  return $got_arrayref ? $args[0]
                       : join(' ', @args);
}


### XXX this is cribbed STRAIGHT from M::B 0.30 here:
### http://search.cpan.org/src/KWILLIAMS/Module-Build-0.30/lib/Module/Build/Platform/Windows.pm:split_like_shell
### XXX this *should* be integrated into text::parsewords
sub _split_like_shell_win32 {
  # As it turns out, Windows command-parsing is very different from
  # Unix command-parsing.  Double-quotes mean different things,
  # backslashes don't necessarily mean escapes, and so on.  So we
  # can't use Text::ParseWords::shellwords() to break a command string
  # into words.  The algorithm below was bashed out by Randy and Ken
  # (mostly Randy), and there are a lot of regression tests, so we
  # should feel free to adjust if desired.

  local $_ = shift;

  my @argv;
  return @argv unless defined() &amp;&amp; length();

  my $arg = '';
  my( $i, $quote_mode ) = ( 0, 0 );

  while ( $i &lt; length() ) {

    my $ch      = substr( $_, $i  , 1 );
    my $next_ch = substr( $_, $i+1, 1 );

    if ( $ch eq '\\' &amp;&amp; $next_ch eq '"' ) {
      $arg .= '"';
      $i++;
    } elsif ( $ch eq '\\' &amp;&amp; $next_ch eq '\\' ) {
      $arg .= '\\';
      $i++;
    } elsif ( $ch eq '"' &amp;&amp; $next_ch eq '"' &amp;&amp; $quote_mode ) {
      $quote_mode = !$quote_mode;
      $arg .= '"';
      $i++;
    } elsif ( $ch eq '"' &amp;&amp; $next_ch eq '"' &amp;&amp; !$quote_mode &amp;&amp;
          ( $i + 2 == length()  ||
        substr( $_, $i + 2, 1 ) eq ' ' )
        ) { # for cases like: a"" =&gt; [ 'a' ]
      push( @argv, $arg );
      $arg = '';
      $i += 2;
    } elsif ( $ch eq '"' ) {
      $quote_mode = !$quote_mode;
    } elsif ( $ch eq ' ' &amp;&amp; !$quote_mode ) {
      push( @argv, $arg ) if defined( $arg ) &amp;&amp; length( $arg );
      $arg = '';
      ++$i while substr( $_, $i + 1, 1 ) eq ' ';
    } else {
      $arg .= $ch;
    }

    $i++;
  }

  push( @argv, $arg ) if defined( $arg ) &amp;&amp; length( $arg );
  return @argv;
}



{   use File::Spec;
    use Symbol;

    my %Map = (
        STDOUT =&gt; [qw|&gt;&amp;|, \*STDOUT, Symbol::gensym() ],
        STDERR =&gt; [qw|&gt;&amp;|, \*STDERR, Symbol::gensym() ],
        STDIN  =&gt; [qw|&lt;&amp;|, \*STDIN,  Symbol::gensym() ],
    );

    ### dups FDs and stores them in a cache
    sub __dup_fds {
        my $self    = shift;
        my @fds     = @_;

        __PACKAGE__-&gt;_debug( "# Closing the following fds: @fds" ) if $DEBUG;

        for my $name ( @fds ) {
            my($redir, $fh, $glob) = @{$Map{$name}} or (
                Carp::carp(loc("No such FD: '%1'", $name)), next );

            ### MUST use the 2-arg version of open for dup'ing for
            ### 5.6.x compatibility. 5.8.x can use 3-arg open
            ### see perldoc5.6.2 -f open for details
            open $glob, $redir . fileno($fh) or (
                        Carp::carp(loc("Could not dup '$name': %1", $!)),
                        return
                    );

            ### we should re-open this filehandle right now, not
            ### just dup it
            ### Use 2-arg version of open, as 5.5.x doesn't support
            ### 3-arg version =/
            if( $redir eq '&gt;&amp;' ) {
                open( $fh, '&gt;' . File::Spec-&gt;devnull ) or (
                    Carp::carp(loc("Could not reopen '$name': %1", $!)),
                    return
                );
            }
        }

        return 1;
    }

    ### reopens FDs from the cache
    sub __reopen_fds {
        my $self    = shift;
        my @fds     = @_;

        __PACKAGE__-&gt;_debug( "# Reopening the following fds: @fds" ) if $DEBUG;

        for my $name ( @fds ) {
            my($redir, $fh, $glob) = @{$Map{$name}} or (
                Carp::carp(loc("No such FD: '%1'", $name)), next );

            ### MUST use the 2-arg version of open for dup'ing for
            ### 5.6.x compatibility. 5.8.x can use 3-arg open
            ### see perldoc5.6.2 -f open for details
            open( $fh, $redir . fileno($glob) ) or (
                    Carp::carp(loc("Could not restore '$name': %1", $!)),
                    return
                );

            ### close this FD, we're not using it anymore
            close $glob;
        }
        return 1;

    }
}

sub _debug {
    my $self    = shift;
    my $msg     = shift or return;
    my $level   = shift || 0;

    local $Carp::CarpLevel += $level;
    Carp::carp($msg);

    return 1;
}

sub _pp_child_error {
    my $self    = shift;
    my $cmd     = shift or return;
    my $ce      = shift or return;
    my $pp_cmd  = ref $cmd ? "@$cmd" : $cmd;


    my $str;
    if( $ce == -1 ) {
        ### Include $! in the error message, so that the user can
        ### see 'No such file or directory' versus 'Permission denied'
        ### versus 'Cannot fork' or whatever the cause was.
        $str = "Failed to execute '$pp_cmd': $!";

    } elsif ( $ce &amp; 127 ) {
        ### some signal
        $str = loc( "'%1' died with signal %2, %3 coredump",
               $pp_cmd, ($ce &amp; 127), ($ce &amp; 128) ? 'with' : 'without');

    } else {
        ### Otherwise, the command run but gave error status.
        $str = "'$pp_cmd' exited with value " . ($ce &gt;&gt; 8);
    }

    $self-&gt;_debug( "# Child error '$ce' translated to: $str" ) if $DEBUG;

    return $str;
}

1;

__END__

=head2 $q = QUOTE

Returns the character used for quoting strings on this platform. This is
usually a C&lt;'&gt; (single quote) on most systems, but some systems use different
quotes. For example, C&lt;Win32&gt; uses C&lt;"&gt; (double quote).

You can use it as follows:

  use IPC::Cmd qw[run QUOTE];
  my $cmd = q[echo ] . QUOTE . q[foo bar] . QUOTE;

This makes sure that C&lt;foo bar&gt; is treated as a string, rather than two
separate arguments to the C&lt;echo&gt; function.

=head1 HOW IT WORKS

C&lt;run&gt; will try to execute your command using the following logic:

=over 4

=item *

If you have C&lt;IPC::Run&gt; installed, and the variable C&lt;$IPC::Cmd::USE_IPC_RUN&gt;
is set to true (See the L&lt;"Global Variables"&gt; section) use that to execute
the command. You will have the full output available in buffers, interactive commands
are sure to work  and you are guaranteed to have your verbosity
settings honored cleanly.

=item *

Otherwise, if the variable C&lt;$IPC::Cmd::USE_IPC_OPEN3&gt; is set to true
(See the L&lt;"Global Variables"&gt; section), try to execute the command using
L&lt;IPC::Open3&gt;. Buffers will be available on all platforms,
interactive commands will still execute cleanly, and also your verbosity
settings will be adhered to nicely;

=item *

Otherwise, if you have the C&lt;verbose&gt; argument set to true, we fall back
to a simple C&lt;system()&gt; call. We cannot capture any buffers, but
interactive commands will still work.

=item *

Otherwise we will try and temporarily redirect STDERR and STDOUT, do a
C&lt;system()&gt; call with your command and then re-open STDERR and STDOUT.
This is the method of last resort and will still allow you to execute
your commands cleanly. However, no buffers will be available.

=back

=head1 Global Variables

The behaviour of IPC::Cmd can be altered by changing the following
global variables:

=head2 $IPC::Cmd::VERBOSE

This controls whether IPC::Cmd will print any output from the
commands to the screen or not. The default is 0.

=head2 $IPC::Cmd::USE_IPC_RUN

This variable controls whether IPC::Cmd will try to use L&lt;IPC::Run&gt;
when available and suitable.

=head2 $IPC::Cmd::USE_IPC_OPEN3

This variable controls whether IPC::Cmd will try to use L&lt;IPC::Open3&gt;
when available and suitable. Defaults to true.

=head2 $IPC::Cmd::WARN

This variable controls whether run-time warnings should be issued, like
the failure to load an C&lt;IPC::*&gt; module you explicitly requested.

Defaults to true. Turn this off at your own risk.

=head2 $IPC::Cmd::INSTANCES

This variable controls whether C&lt;can_run&gt; will return all instances of
the binary it finds in the C&lt;PATH&gt; when called in a list context.

Defaults to false, set to true to enable the described behaviour.

=head2 $IPC::Cmd::ALLOW_NULL_ARGS

This variable controls whether C&lt;run&gt; will remove any empty/null arguments
it finds in command arguments.

Defaults to false, so it will remove null arguments. Set to true to allow
them.

=head1 Caveats

=over 4

=item Whitespace and IPC::Open3 / system()

When using C&lt;IPC::Open3&gt; or C&lt;system&gt;, if you provide a string as the
C&lt;command&gt; argument, it is assumed to be appropriately escaped. You can
use the C&lt;QUOTE&gt; constant to use as a portable quote character (see above).
However, if you provide an array reference, special rules apply:

If your command contains B&lt;special characters&gt; (&lt; &gt; | &amp;), it will
be internally stringified before executing the command, to avoid that these
special characters are escaped and passed as arguments instead of retaining
their special meaning.

However, if the command contained arguments that contained whitespace,
stringifying the command would lose the significance of the whitespace.
Therefore, C&lt;IPC::Cmd&gt; will quote any arguments containing whitespace in your
command if the command is passed as an arrayref and contains special characters.

=item Whitespace and IPC::Run

When using C&lt;IPC::Run&gt;, if you provide a string as the C&lt;command&gt; argument,
the string will be split on whitespace to determine the individual elements
of your command. Although this will usually just Do What You Mean, it may
break if you have files or commands with whitespace in them.

If you do not wish this to happen, you should provide an array
reference, where all parts of your command are already separated out.
Note however, if there are extra or spurious whitespaces in these parts,
the parser or underlying code may not interpret it correctly, and
cause an error.

Example:
The following code

    gzip -cdf foo.tar.gz | tar -xf -

should either be passed as

    "gzip -cdf foo.tar.gz | tar -xf -"

or as

    ['gzip', '-cdf', 'foo.tar.gz', '|', 'tar', '-xf', '-']

But take care not to pass it as, for example

    ['gzip -cdf foo.tar.gz', '|', 'tar -xf -']

Since this will lead to issues as described above.


=item IO Redirect

Currently it is too complicated to parse your command for IO
redirections. For capturing STDOUT or STDERR there is a work around
however, since you can just inspect your buffers for the contents.

=item Interleaving STDOUT/STDERR

Neither IPC::Run nor IPC::Open3 can interleave STDOUT and STDERR. For short
bursts of output from a program, e.g. this sample,

    for ( 1..4 ) {
        $_ % 2 ? print STDOUT $_ : print STDERR $_;
    }

IPC::[Run|Open3] will first read all of STDOUT, then all of STDERR, meaning
the output looks like '13' on STDOUT and '24' on STDERR, instead of

    1
    2
    3
    4

This has been recorded in L&lt;rt.cpan.org&gt; as bug #37532: Unable to interleave
STDOUT and STDERR.

=back

=head1 See Also

L&lt;IPC::Run&gt;, L&lt;IPC::Open3&gt;

=head1 ACKNOWLEDGEMENTS

Thanks to James Mastros and Martijn van der Streek for their
help in getting L&lt;IPC::Open3&gt; to behave nicely.

Thanks to Petya Kohts for the C&lt;run_forked&gt; code.

=head1 BUG REPORTS

Please report bugs or other issues to E&lt;lt&gt;bug-ipc-cmd@rt.cpan.orgE&lt;gt&gt;.

=head1 AUTHOR

Original author: Jos Boumans E&lt;lt&gt;kane@cpan.orgE&lt;gt&gt;.
Current maintainer: Chris Williams E&lt;lt&gt;bingos@cpan.orgE&lt;gt&gt;.

=head1 COPYRIGHT

This library is free software; you may redistribute and/or modify it
under the same terms as Perl itself.

=cut
</pre></body></html>