<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::Event::Ok;
use strict;
use warnings;

our $VERSION = '1.302133';


BEGIN { require Test2::Event; our @ISA = qw(Test2::Event) }
use Test2::Util::HashBase qw{
    pass effective_pass name todo
};

sub init {
    my $self = shift;

    # Do not store objects here, only true or false
    $self-&gt;{+PASS} = $self-&gt;{+PASS} ? 1 : 0;
    $self-&gt;{+EFFECTIVE_PASS} = $self-&gt;{+PASS} || (defined($self-&gt;{+TODO}) ? 1 : 0);
}

{
    no warnings 'redefine';
    sub set_todo {
        my $self = shift;
        my ($todo) = @_;
        $self-&gt;{+TODO} = $todo;
        $self-&gt;{+EFFECTIVE_PASS} = defined($todo) ? 1 : $self-&gt;{+PASS};
    }
}

sub increments_count { 1 };

sub causes_fail { !$_[0]-&gt;{+EFFECTIVE_PASS} }

sub summary {
    my $self = shift;

    my $name = $self-&gt;{+NAME} || "Nameless Assertion";

    my $todo = $self-&gt;{+TODO};
    if ($todo) {
        $name .= " (TODO: $todo)";
    }
    elsif (defined $todo) {
        $name .= " (TODO)"
    }

    return $name;
}

sub extra_amnesty {
    my $self = shift;
    return unless defined($self-&gt;{+TODO}) || ($self-&gt;{+EFFECTIVE_PASS} &amp;&amp; !$self-&gt;{+PASS});
    return {
        tag       =&gt; 'TODO',
        details   =&gt; $self-&gt;{+TODO},
    };
}

sub facet_data {
    my $self = shift;

    my $out = $self-&gt;common_facet_data;

    $out-&gt;{assert}  = {
        no_debug =&gt; 1,                # Legacy behavior
        pass     =&gt; $self-&gt;{+PASS},
        details  =&gt; $self-&gt;{+NAME},
    };

    if (my @exra_amnesty = $self-&gt;extra_amnesty) {
        unshift @{$out-&gt;{amnesty}} =&gt; @exra_amnesty;
    }

    return $out;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::Event::Ok - Ok event type

=head1 DESCRIPTION

Ok events are generated whenever you run a test that produces a result.
Examples are C&lt;ok()&gt;, and C&lt;is()&gt;.

=head1 SYNOPSIS

    use Test2::API qw/context/;
    use Test2::Event::Ok;

    my $ctx = context();
    my $event = $ctx-&gt;ok($bool, $name, \@diag);

or:

    my $ctx   = context();
    my $event = $ctx-&gt;send_event(
        'Ok',
        pass =&gt; $bool,
        name =&gt; $name,
    );

=head1 ACCESSORS

=over 4

=item $rb = $e-&gt;pass

The original true/false value of whatever was passed into the event (but
reduced down to 1 or 0).

=item $name = $e-&gt;name

Name of the test.

=item $b = $e-&gt;effective_pass

This is the true/false value of the test after TODO and similar modifiers are
taken into account.

=back

=head1 SOURCE

The source code repository for Test2 can be found at
F&lt;http://github.com/Test-More/test-more/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2018 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>